Lat/Long in MapPoint 2002

Subscribe

Magazine

Front Cover
What's New
Articles
News
Sample Data
Gallery
Advertise
About

Features

MapPoint 2011
Press Releases
MapPoint Forums
Companies
Link to MP2Kmag
Wish List
MapPoint Trial
Authors

Earlier Content

Past News Items
Past What's New Announcements

Sponsors

Order

MapPoint 2011

Programming MapPoint in .NET

MapPoint Book

Spatial Community

SVG Tutorials
MapPoint


	ARTICLES

Chris Gebhardt shares some insights into how to circumvent the lack of a lat/long support in MP. "There are ways to ascertain the lat/long using simple geometry and trigonometry."

Greetings all,

I too have been extremely frustrated with lack of a lat/long in MP. I thoroughly understand Microsoft's reasoning as it is contractual between MS and their partners. However, as lccox pointed out, there are ways to ascertain the lat/long using simple geometry and trigonometry. Rather than tell you about it or how to do it, I have decided to share the code with you.

Below, you will see the GetLatLong procedure I call from a form. If anyone is interested, I have a complete VB Project that shows how to use this code. If you have any questions, please feel free to e-mail me.

Chris Gebhardt
Crime Analysis Associates
www.CrimeAnalysis.net
chris @ Crime Analysis . Net

Begin Code:

'Latitude/Longitude Discovery Module (v1.0, June 5, 2001)
'Created by Christopher S. Gebhardt
'Crime Analysis Associates
'www.CrimeAnalysis.net
'Chris @ Crime Analysis . net
'
'This code is hereby released into the public domain.  Please forward any suggestions
'or additions to the author.  If you decide to use this code snippet, leave this  
'header information intact to give credit to the author!

Sub GetLatLong(Street As String, City As String, State As String)
    Dim oApp As MapPoint.Application, oMap As MapPoint.Map
    Dim oPush As MapPoint.Pushpin, oPushA As MapPoint.Pushpin
    Dim oLoc As MapPoint.Location, oLocA As MapPoint.Location, oLocB As MapPoint.Location
    'A Mile = 0.01471 Degrees of Lat/Long, a Half mile = 0.007355
    Dim Measure As Double
    Dim zLat As Double, zLong As Double, DistX As Double, DistY As Double, DistZ As Double
    Dim PointX As MapPoint.Location, PointY As MapPoint.Location

    Set oApp = CreateObject("Mappoint.Application")
    Set oMap = oApp.ActiveMap

    'myLat and myLong are a known point.  In this case, Wichita, Kansas
    myLat = 37.70212
    myLong = -97.31775

    'Initially, set zLat and zLong equal to the known point
    zLat = myLat
    zLong = myLong

    'Measure is used to adjust the starting distance. In this case, start off with 750 miles.
    'Measure is made smaller in the Do While loop below but it is a good idea to start off
    'with a large number
    Measure = 0.01471 * 750

    'Create two points: oLoc as the reference point and your address for which you need lat/long
    Set oLoc = oMap.GetLocation(myLat, myLong)
    'Find your address from the form frmLatLong
    Set oPushA = oMap.ShowFindDialog(Street & ", " & City & ", " & State, , , True)
    On Error GoTo EndNow 'If there is no address found, then Set oLocA will fail.
    Set oLocA = oPushA.Location
    On Error Resume Next

    'Update the form with the chosen address from the Find Dialog
    frmLatLong.txtStreet = oMap.ParseStreetAddress(oPushA.Name).Street
    frmLatLong.txtCity = oMap.ParseStreetAddress(oPushA.Name).City
    frmLatLong.txtState = oMap.ParseStreetAddress(oPushA.Name).Region

    x = 0
    'Create a loop that will continue until your desired precision.  As indicated below
    'this loop will repeat until the lat/long is found to be within 20 feet.
    Do While Measure > 0.00005572   'This value is determined using the following formula:
                                    '   .01471/5280*Number of Feet for Precision
                                    '  Ex:  .01471 / 5290 * 20 = .00005572
                                    '  Trivia: There are 5,280 feet in a mile.
        x = x + 1

        'Create two other reference points: PointX is one Measure off oLoc's Lattitude
        '                                   PointY is one Measure off oLoc's Longitude
        Set PointX = oMap.GetLocation(zLat + Measure, zLong)
        Set PointY = oMap.GetLocation(zLat, zLong + Measure)

        'Measure the distances from each of the three reference points to our main address (oLocA)
        DistX = oLocA.DistanceTo(PointX)
        DistY = oLocA.DistanceTo(PointY)
        DistZ = oLocA.DistanceTo(oLoc)

        'Determine which reference point is closer to oLocA, our main address
        If DistX < DistY And DistX < DistZ Then
            'Make the master reference point oLoc equal to PointX since PointX was the closest to
            'our main address
            Set oLoc = oMap.GetLocation(zLat + Measure, zLong)
            zLat = zLat + Measure  'Don't forget to add the Measure to zLat for the next iteration
            'Uncomment the next line if you want to see how the algorithm found the lat/long
            'Set oPush = oMap.AddPushpin(oMap.GetLocation(zLat + Measure, zLong), x)
        End If
        If DistY < DistX And DistY < DistZ Then
            Set oLoc = oMap.GetLocation(zLat, zLong + Measure)
            zLong = zLong + Measure
            'Set oPush = oMap.AddPushpin(oMap.GetLocation(zLat, zLong + Measure), x)
        End If
        If DistZ < DistX And DistZ < DistY Then
            'The main reference point is closer than PointX or PointY.
            'PointX and PointY were too far away by ADDING a Measure, so here we need
            'to subtract a measure from both the Latitude and the Longitude
            Set oLoc = oMap.GetLocation(zLat - Measure, zLong - Measure)
            zLat = zLat - Measure
            zLong = zLong - Measure
            'Set oPush = oMap.AddPushpin(oMap.GetLocation(zLat - Measure, zLong - Measure), x)
        End If

        'Here is where Measure gets adjusted.  Check to see if the distance between the new
        'reference point is smaller than Measure.  If so, reduce Measure by half.
        'Don't forget that Measure is in degrees of Lat/Long while the distance will be
        'in miles.  To convert degrees to miles, multiply by .01471, the number of degrees
        'in a mile.
        If oLocA.DistanceTo(oLoc) < Measure / 0.01471 Then Measure = Measure / 2
    Loop

    'Create a PushPin with the new location that matches our address
    'Add how many iterations of the loop it took (x) and the the Latitude, Longitude
    Set oPush = oMap.AddPushpin(oLoc, x & ": " & zLat & ", " & zLong)

    MsgBox "The Lat/Long of your address is " & zLat & ", " & zLong & _
        Chr(13) & Chr(13) & "It was found in " & x & " iterations.", _
        vbOKOnly, "Lat/Long Results"

    'The next four lines are just for presentation.  Uncomment them if you like
    'oPush.BalloonState = geoDisplayBalloon 'Turn on the balloon state so we can see the lat/long
    'oPush.Highlight = True 'Highlight the pushpin so we really see it
    'oMap.DataSets.ZoomTo 'Zoom the map to the individual pushpin
    'oApp.Visible = True 'Turn on the map so we can see it!

EndNow:
    oMap.Saved = True
End Sub

Discuss this story in the forum.

Author: Christopher Gebhardt
Email: Chris(AT)CrimeAnalysis.net
URL: http://www.crimeanalysis.net
Chris Gebhardt is the Director of Marketing for CRISNet (www.crisnet.com) in Salt Lake City, Utah. He is also the CEO of Crime Analysis Associates (www.CrimeAnalysis.net) where he uses Microsoft products and specifically MapPoint in the creation of his Crime Analysis software.

Chris is a former Lieutenant with the Metropolitan Police Department in Washington, D.C. where he was the Commander of the Tactical Crime Analysis Unit responsible for crime analysis and crime mapping. This job is the basis for the TV show "The District."

In his spare time, Chris is the Technical Advisor to the California Crime and Intelligence Analysts Association (www.CrimeAnalyst.org).

Chris can be reached at chris@crimeanalysis.net.

Recent Discussion

-bingmaps: RT @ChrisPendleton: In case you missed my #location2012 talk, @OrdnanceSurvey has posted a recording: http://t.co/p5dcMTpN
-Upcoming WhereCamp Berlin 2012
-MapPoint for World Maps?
-Beginner stuck-what am I doing wrong?
-Mappoint 2011 Europe -> tooltip and update possibilities
-bingmaps: FREE BING MAPS EVENTS IN GERMANY: M�nchen https://t.co/pFJZxDdE K�ln https://t.co/zerD99GK #bingmaps
-bingmaps: FREE EVENT: @BingMaps and @Beyond present a vision of the London 2012 Games: The Most Connected Games Ever. https://t.co/yEJ493OR
-Need Several Radius imported into a map
-Automatic generation of Drive Time zones around PushPins
-C# Code To Load Older COM Version
-Successful MapPoint Web Service (MWS) to Bing Maps Conversion
-bingmaps: @Sonray Please direct your question to our technical forum which is monitored by our developers: http://t.co/dEfOwFBC
-bingmaps: New Bird�s Eye Imagery & Streetside Coverage on Bing Maps! http://t.co/iJPu0McQ
-I have an excel spreadsheet that has number of houses on roads, can I link this to mappoint?
-Microsoft MapPoint 2011 Construction Data Update May 4th, 2012
-Mappoint 2011 and the built in database
-Using Excel and mappoint
-Extracting ZipCode With Lat/Long
-DataLink Problem!
-bingmaps: Integrating Bing Maps With WPF:http://t.co/HzdriaMs
-Mapping Bears
-Route Segments do not add up to complete route
-plotting pie charts by sales numbers
-Importing Live Data into Mapoint
-number of houses on a road?

Resources

Browse GIS books and periodicals
Find a MapPoint Partner or Consultant
Real Estate Columbia, MO Real Estate

Want Your Site To Appear Here?

© 1999-2012 MP2K. Questions and comments to: website@mp2kmag.com
Microsoft and MapPoint 2002/2004/2006/2009/2010/2011 are either trademarks or registered trademarks of Microsoft.